In dem Script wird auch geprüft ob dies hinzufügende IP Adresse schon vorhanden ist und dementsprechend wird mit der nächsten IP Adresse weiter gearbeitet.

Hier nun das Script:

:: Autor Knut Herter
:: Datum 1.10.2023
::
:: Zweck : In die lokale Hosts Datei muessen der Eintraege a la w.x.y.z www.meine-testdomain.de 
:: hinzugefuegt werden sofern dieser nicht vorhanden sind
::
::@echo off
setlocal enabledelayedexpansion

set "hosts_file=%SystemRoot%\System32\drivers\etc\hosts"

rem Stelle sicher, dass die Eingabedatei vorhanden ist und setze sie als Eingabequelle
set "input_file=input.txt"
if not exist "!input_file!" (
    echo Eingabedatei "!input_file!" nicht gefunden.
    exit /b
)

rem Schleife zum Lesen der Eingabedatei
for /f "tokens=1,2" %%a in (!input_file!) do (
    set "ip_to_check=%%a"
    set "hostname=%%b"

    rem Überprüfen, ob die IP bereits in der Hosts-Datei vorhanden ist
    findstr /C:"!ip_to_check!" "!hosts_file!" >nul
    if !errorlevel! neq 0 (
        echo IP-Adresse !ip_to_check! für !hostname! nicht gefunden. Füge sie hinzu.

        rem IP-Adresse und Hostname zur Hosts-Datei hinzufügen
        echo !ip_to_check!    !hostname! >> "!hosts_file!"
    ) else (
        echo IP-Adresse !ip_to_check! für !hostname! bereits in der Hosts-Datei vorhanden.
    )
)

endlocal

Das Script erwartet die Datei input.txt und muss mit administrativen Rechten gestartet werden. In dieser sehen die Einträge in folgender Form. Ist die Datei nicht vorhanden, dann wir die komplette Verarbeitung abgebrochen.

192.168.1.100 example1.com
10.0.0.1 example2.com
192.168.2.200 example3.com

Natürlich kann man das Script auch ein Domänenumgebung mit einer GPO verwenden.

Möchte man nur eine einzelne IP Adresse aufnehmen, dann kann man auch folgendes Script verwenden: KLICK

Möchte man dies wieder rückgängig machen kann folgendes Script verwendet werden.

:: Autor Knut Herter
:: Datum 29.09.2023
::
@echo off
setlocal enabledelayedexpansion

set "ip_to_delete=w.x.y.z"
set "hosts_file=%SystemRoot%\System32\drivers\etc\hosts"

rem Überprüfen, ob die IP-Adresse in der Hosts-Datei vorhanden ist
findstr /C:"!ip_to_delete!" "!hosts_file!" >nul
if !errorlevel! equ 0 (
    echo IP-Adresse !ip_to_delete! gefunden. Lösche sie.

    rem Temporäre Datei erstellen
    set "temp_file=%temp%\hosts_temp.txt"

    rem Zeilen ohne die zu löschende IP-Adresse in die temporäre Datei kopieren
    findstr /v /C:"!ip_to_delete!" "!hosts_file!" > "!temp_file!"

    rem Die temporäre Datei zur Hosts-Datei kopieren
    copy /y "!temp_file!" "!hosts_file!" >nul

    rem Temporäre Datei löschen
    del "!temp_file!" >nul

    echo IP-Adresse !ip_to_delete! wurde aus der Hosts-Datei gelöscht.
) else (
    echo IP-Adresse !ip_to_delete! nicht gefunden in der Hosts-Datei.
)

endlocal

Das Script selbst muss natürlich mit administrative Rechten gestartet werden. In einer Domänenumgebung geht dies auch, wie in dem Artikel zuvor, mit einer Gruppenrichtlinie (GPO)

Es sucht nach einer bestimmten IP Adresse. Ist diese nicht vorhanden, dann wird diese inkl. des Hostnamen eingefügt.

:: Autor Knut Herter
:: Datum 22.09.2023
::
:: Zweck : In die lokale Hosts Datei muss der Eintrag w.x.y.z www.meine-testdomain.de 
:: hinzugefuegt werden sofern dieser nicht vorhanden ist
::
::
@echo off
setlocal enabledelayedexpansion

set "ip_to_check=w.x.y.z"
set "hosts_file=%SystemRoot%\System32\drivers\etc\hosts"

rem Überprüfen, ob die IP bereits in der Hosts-Datei vorhanden ist
findstr /C:"%ip_to_check%" "%hosts_file%" >nul
if %errorlevel% neq 0 (
    echo IP-Adresse nicht gefunden. Fuege sie hinzu.
    echo %ip_to_check%    www.meine-testdomain.de >> "%hosts_file%"

) else (
    echo IP-Adresse bereits in der Hosts-Datei vorhanden.
)

endlocal

Das Script muss natürlich mit administrativen rechten gestartet werden. Mit einem weiteren Script lässt sich dies auch wieder zurück ändern.

In einer Domänenumgebung kann man dies natürlich über eine entsprechende Gruppenrichtlinie erledigen lassen.