reg add HKEY_CURRENT_USER\Software\Policies\Microsoft\office\16.0\outlook\preferences  /t REG_DWORD /v NewOutlookMigrationUserSetting /d 0

(Achtung: Das Code Plugin macht aus office\16.0\outlook ein office.0\outlook. )

Das Original Script ist deskmodder entnommen, ich habe es noch um eine Abfrage erweitert ob dieses auch wirklich als Administrator gestartet wurde.

@echo off
cls

:abfrage
CHOICE /C JN /M "Batch als Administrator gestartet?"
IF %ERRORLEVEL% EQU 1 goto starte
echo Bitte starte das Script mit der rechten Maustaste
echo Als Administrator starten
goto ende

:starte
set x86="%SYSTEMROOT%\System32\OneDriveSetup.exe"
set x64="%SYSTEMROOT%\SysWOW64\OneDriveSetup.exe"

echo OneDrive beenden
echo.
taskkill /f /im OneDrive.exe > NUL 2>&1
ping 127.0.0.1 -n 5 > NUL 2>&1

echo OneDrive deinstallieren
echo.
if exist %x64% (
%x64% /uninstall
) else (
%x86% /uninstall
)
ping 127.0.0.1 -n 5 > NUL 2>&1

echo OneDrive letzte Reste entfernen
echo.
rd "%USERPROFILE%\OneDrive" /Q /S > NUL 2>&1
rd "C:\OneDriveTemp" /Q /S > NUL 2>&1
rd "%LOCALAPPDATA%\Microsoft\OneDrive" /Q /S > NUL 2>&1
rd "%PROGRAMDATA%\Microsoft OneDrive" /Q /S > NUL 2>&1

echo OneDrive aus Datei Explorer entfernen
echo.
REG DELETE "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
REG DELETE "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
REG DELETE "HKEY_CURRENT_USER\Software\Classes\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}\ShellFolder" /f > NUL 2>&1
REG DELETE "HKEY_CURRENT_USER\Software\Classes\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}\ShellFolder" /f > NUL 2>&1

pause

:ende

In dem Script wird auch geprüft ob dies hinzufügende IP Adresse schon vorhanden ist und dementsprechend wird mit der nächsten IP Adresse weiter gearbeitet.

Hier nun das Script:

:: Autor Knut Herter
:: Datum 1.10.2023
::
:: Zweck : In die lokale Hosts Datei muessen der Eintraege a la w.x.y.z www.meine-testdomain.de 
:: hinzugefuegt werden sofern dieser nicht vorhanden sind
::
::@echo off
setlocal enabledelayedexpansion

set "hosts_file=%SystemRoot%\System32\drivers\etc\hosts"

rem Stelle sicher, dass die Eingabedatei vorhanden ist und setze sie als Eingabequelle
set "input_file=input.txt"
if not exist "!input_file!" (
    echo Eingabedatei "!input_file!" nicht gefunden.
    exit /b
)

rem Schleife zum Lesen der Eingabedatei
for /f "tokens=1,2" %%a in (!input_file!) do (
    set "ip_to_check=%%a"
    set "hostname=%%b"

    rem Überprüfen, ob die IP bereits in der Hosts-Datei vorhanden ist
    findstr /C:"!ip_to_check!" "!hosts_file!" >nul
    if !errorlevel! neq 0 (
        echo IP-Adresse !ip_to_check! für !hostname! nicht gefunden. Füge sie hinzu.

        rem IP-Adresse und Hostname zur Hosts-Datei hinzufügen
        echo !ip_to_check!    !hostname! >> "!hosts_file!"
    ) else (
        echo IP-Adresse !ip_to_check! für !hostname! bereits in der Hosts-Datei vorhanden.
    )
)

endlocal

Das Script erwartet die Datei input.txt und muss mit administrativen Rechten gestartet werden. In dieser sehen die Einträge in folgender Form. Ist die Datei nicht vorhanden, dann wir die komplette Verarbeitung abgebrochen.

192.168.1.100 example1.com
10.0.0.1 example2.com
192.168.2.200 example3.com

Natürlich kann man das Script auch ein Domänenumgebung mit einer GPO verwenden.

Möchte man nur eine einzelne IP Adresse aufnehmen, dann kann man auch folgendes Script verwenden: KLICK

Mit dem Befehl cmdkey.exe kann man diese mit Skripten ganz gut bearbeiten. Hier ein paar Beispiele:

Anmeldeinfo zu einem Serverlaufwerk hinzufügen:

cmdkey /add:*.lix.net /user: lix\knut /pass:geheimes_passwort

Eine bestimmte Anmeldeinfo löschen:

cmdkey /delete Domain:target=*.lix.net

Mehrere Anmeldeinfos (nach Suchkriterium) löschen:

for /F "tokens=1,* delims= " %G in ('cmdkey /list ^| findstr 10.10.10.') do cmdkey /delete %H

Anmeldeinfos auflisten

cmdkey /list

Zuerst lesen wir die Gruppenliste des Referenznutzers KMustermann in die Variable Gruppenliste.

$Gruppenliste = Get-ADUser -Properties MemberOf -Identity 'KMustermann'

Im Anschluss übertragen wir die diese Gruppen mit dem zweiten Befehl zu dem Nutzer KHerter.

Add-ADPrincipalGroupMembership -MemberOf $Gruppenliste.MemberOf -Identity 'KHerter' 

Sind bei dem Zielnutzer (KHerter) schon diverse Gruppen enthalten, so werden die Gruppen des Referenznutzers (KMustermann) addiert. Eine entsprechende Fehlermeldung, falls eventuelle Nutzergruppen schon vorhanden, sind gibt es nicht.

Das Schema läuft im Prinzip wie folgt ab:

:: Update notwendig? 
 if exist "\\server-01\merker\%computername%-%username%-meineDB.txt" echo Kein Update notwendig
 if exist "\\server-01\merker\%computername%-%username%-meineDB.txt" goto FIN

:: Datenbank muss frisch kopiert werden
xcopy \\server-01\software\meineDB.accdr %userprofile%\meineDB.accdr /R /Y
echo 1 > "\\server-01\merker\%computername%-%username%-meineDB.txt"

:FIN

In Zeile zwei und drei prüfe ich das vorhanden sein einer Datei auf dem Server-01 ab. In das Verzeichnis/Freigabe Merker muss natürlich die Gruppe jeder Schreib- und Leserechte besitzen. Ist die Datei vorhanden, dann springe ich ab Zeile drei zur Sprungmarke FIN.

Ab Zeile 5 können nun Dinge einmalig durchgeführt werden. Am Ende der Verarbeitung (Zeile 7) muss natürlich die Merk-Datei geschrieben werden. Beim zweiten Lauf des Skriptes wird also nichts mehr verarbeitet.

Möchte ich einem bestimmten Nutzer/Computer ein Update bereitstellen, so brauche ich nur die entsprechende Merk-Datei löschen und diesen neu anmelden lassen.

Der zu importierende Key wäre folgender:

Windows Registry Editor Version 5.00 
[HKEY_CURRENT_USER\SOFTWARE\Microsoft\Office\16.0\Access\Security\Trusted Locations\Location0] 
"Path"="C:\\Users\\Knut.lixd\\AppData\\Roaming\\MyAccessApp\\"
"Description"=""
"Date"="16/06/2022 9:20"

Das Problem dabei: Im Pfad steht nicht nur mein Name Knut ( %username%) sondern auch die Domäne (lixd). Somit kann ich die Umgebungsvariable %Username% nicht einfach verwenden und muss mir dies anders zusammenbauen. Verwende ich %Userprofile%, dann fehlen mir die doppelten „\“.
Die Idee war nun aus %Userprofile% das C:\Users zu entfernen und in den String oben einzubauen.

Dies geht am einfachsten wie folgt:

@echo off
setlocal enabledelayedexpansion
set "uprofile=%userprofile%"
set "uprofile=!uprofile:C:\Users\=!"
echo %uprofile%

In der Variable die Variable uprofile kann ich nun weiter verwenden um mir eine Registry (trust.reg) Datei für den Import (reg Import trust.reg /reg:64) zu bauen:

:: Trustcenter bearbeiten
echo Bearbeite Trustcenter
echo Windows Registry Editor Version 5.00 > %temp%\trust.reg
echo [HKEY_CURRENT_USER\SOFTWARE\Microsoft\Office\16.0\Access\Security\Trusted Locations\Location0] >> %temp%\trust.reg
echo "Path"="C:\\Users\\%uprofile%\\AppData\\Roaming\\MyAccessApp\\"  >> %temp%\trust.reg
echo "Description"=""  >> %temp%\trust.reg
echo "Date"="16/06/2022 9:20"  >> %temp%\trust.reg
reg import %temp%\trust.reg /reg:64
del %temp%\trust.reg

Damit dies nicht bei jedem Batch lauf passiert sollte man sich entsprechende Marker setzten und entsprechend abfragen. Per Datei oder Registry Eintrag, je nach belieben. Dies beschreibe ich (vermutlich) man in einem anderen Beitrag.

Zwei Gedanken noch dazu:

• Ist in der Registry Location0 schon vorhanden, so wird diese überschrieben. Das kann man sicherlich besser lösen, war bei dem Kunden mit komplett neuen Benutzerprofilen nicht von Relevanz.
• Das Benutzerprofil muss nicht zwingender Weise auf C: liegen. Bei Servergespeicherten Profilen muss man den String anders zusammenbauen. ( set „uprofile=!uprofile:\=\\!“ )

echo off
cls

:: Variablen setzen

:: Bei Bedarf Variablen anpassen
::
set IconTitle="%HomePath%\desktop\Fernwartung SystemTechnics.lnk"
set Target="https://www.systemtechnics.de/fernwartung/"
set WorkingDirectory="%temp%"
set Description="Download Link zum aktuellen Teamviewer"
set VBSFile=%date%-sc001
set IconNum=15

:: Hier nichts mehr anpassen
::

cls
echo .........................................................
echo .
echo . Erstelle Icon %IconTitle% - %Target%
echo .
echo .........................................................

:: Datum wg. Temp-File ermitteln
for /f "tokens=1-4" %%a in ('cmd.exe /c "echo. | date"') do if %%a == Aktuelles set date=%%d

:: Icon auf Desktop vorhanden?
if exist %IconTitle% echo Icon vorhanden
::if exist %IconTitle% goto icon_skip

:: Temp VBScript anlegen
::
 >%temp%\%VBSFile%.vbs echo Set objShell=WScript.CreateObject("Wscript.Shell")
>>%temp%\%VBSFile%.vbs echo Set objShortcut=objShell.CreateShortcut(%IconTitle%)
>>%temp%\%VBSFile%.vbs echo objShortcut.TargetPath=%Target%
>>%temp%\%VBSFile%.vbs echo objShortcut.Description=%Description%
>>%temp%\%VBSFile%.vbs echo objShortcut.WorkingDirectory=%WorkingDirectory%
>>%temp%\%VBSFile%.vbs echo objShortCut.IconLocation = "C:\Windows\SystemResources\shell32.dll.mun, %IconNum%"
>>%temp%\%VBSFile%.vbs echo objShortcut.Save

::... anschliessend starten ...
cscript //nologo %temp%\%VBSFile%.vbs

::... und wieder entfernen.
del %temp%\%VBSFile%.vbs

:icon_skip
exit

Eine umfangreiche Liste mit freier Icons ist unter https://github.com/topics/icon-pack zu finden. Man kann diese dann sicherlich in eine ICO-Datei exportieren und im Script entsprechend bereitstellen.

Installiert wird WinGet über der Microsoft Appstore. Dazu einfach winget in die Suchzeile eingeben und installieren.

Anschließend kann man in der Powershell (oder Command-Box) den Befehl WinGet ausführen. Ohne Parameter wird einem eine Liste möglicher Befehle ausgegeben. WinGet List zeigt z.B. alle installierten Apps an.

Hier meine Apps, die ich eigentlich auf jeden Rechner drauf mache und für notwendig erachte:

winget install 7zip.7zip --accept-package-agreements --silent --accept-source-agreements 
winget install Irfanview -s msstore --accept-package-agreements --silent  
winget install Ghisler.TotalCommander --accept-package-agreements  
winget install Mozilla.Firefox --accept-package-agreements  
winget install Google.Chrome --accept-package-agreements  
winget install "Adobe Acrobat Reader DC" -s msstore --accept-package-agreements  
winget install vlc -s msstore --accept-package-agreements
winget install Notepad++.Notepad++ --accept-package-agreements  
winget install Zoom.Zoom --accept-package-agreements

Zusätzlich vielleicht noch folgende Apps:

winget install HopToDesk --accept-package-agreements
winget install TeamViewer.TeamViewer --accept-package-agreements
winget install TeamViewer.TeamViewer.Host --accept-package-agreements
winget install Putty.Putty --accept-package-agreements
winget install TimKosse.FileZilla.Client --accept-package-agreements
winget install WinSCP.WinSCP --accept-package-agreements
winget install sysinternals --accept-package-agreements

Möchte man eine bestimmte Software installieren, dann kann man den Parameter search (also winget search AppName ) bemühen.

echo off 
cls

::
:: ** Dies Script ermittelt die externe IP, sofern man hinter einem NAT Router sich befindet,
:: ** und schreibt diese in die Datei aus der Variablen "report"

:: **** ein paar Umgebungsvariablen zum anpassen
:: **
::
set report=c:\temp\oeff-ip.txt
set curlpath=curl.exe

:: **********************************************************************************************
:: **** Ab hier nichts mehr anpassen
:: **********************************************************************************************
::

:: Datum und Uhrzeit ermitteln und in Variablen sichern
for /f "tokens=1-3" %%a in ('cmd.exe /c "echo. | time"') do if %%a == Aktuelle set time=%%c
for /f "tokens=1-4" %%a in ('cmd.exe /c "echo. | date"') do if %%a == Aktuelles set date=%%d

echo|set /p="%date% - %time% - IP = " >> %report%
%curlpath% -s http://ip.tx2.net >> %report%
echo. >> %report%

Wer mag kann die Variable report entsprechend anpassen und mittels Aufgabenplanung das Script regelmäßig ausführen lassen.